* Declarao da biblioteca da AluraPlay ;
LIBNAME alura '/folders/myfolders/AluraPlay';

/*
 * GERA OS GRFICOS DA ANLISE NA BASE DE CADASTRO CLIENTE
 */

/*
 * Criamos as variveis de Estado e Idade
 * na base de cadastro dos clientes
 */

PROC FORMAT;
	VALUE estados_
		low-09 = "Grande SP"
		10-19  = "Interior SP"
		20-28  = "Rio de Janeiro"
		30-39  = "Minas Gerais"
		80-87  = "Paran"
		OTHER  = "Demais Estados";
RUN;

DATA alura.CADASTRO_CLIENTE_V3;
set alura.CADASTRO_CLIENTE_V2;

Estado = put(input(substr(CEP,1,2),best.),estados_.);

Idade = intck('YEAR',input(Nascimento,YYMMDD10.),mdy(12,1,2017),'c');

RUN;

/* Gera uma tabela de frequncias das variveis de Estado e Idade */
TITLE "Tabela de clientes por estado e idade";
PROC FREQ
	data=alura.cadastro_cliente_v3;
	table Estado Idade;
RUN;

/* Plota o grfico da varivel Estado */
TITLE "Quantidade de clientes por estado";
PROC SGPLOT
	data=alura.cadastro_cliente_v3;
	vbar Estado / fillattrs=(color=green);
	yaxis label="Nmero de clientes"
		values=(0 to 35 by 5) grid
		minor minorcount=4;
	*title "Quantidade de clientes por estado";
RUN;
TITLE;

/* Plota o grfico da varivel Idade */
TITLE "Nmero de clientes por faixas de idade";
PROC SGPLOT
	data=alura.cadastro_cliente_v3;
	histogram Idade / fillattrs=(color=green);
	yaxis grid minor minorcount=9 label="Nmero de clientes";
	xaxis grid minor minorcount=9 label="Idade (anos)";
RUN;
TITLE;

/* Gera uma anlise univariada da Idade, junto com um histograma */
PROC UNIVARIATE
	data=alura.cadastro_cliente_v3;
	var Idade;
	histogram;
RUN;
